Rumus Terbilang Excel Manual Tanpa Macro Untuk Merubah Angka Menjadi Huruf

Rumus Terbilang Excel - Merubah angka menjadi huruf/teks terbilang otomatis seringkali kita butuhkan saat bekerja dengan microsoft excel. Misalnya saat membuat kwitansi pembayaran. Kasus sprti ini biasanya disebut dengan fungsi atau rumus terbilang excel.

Hal ini mengacu pada pembuatan kwitansi yg biasanya menyebut kalimat terbilang dari nominal rupiah. Misalnya merubah angka Rp. 750.000,- menjadi Tujuhratus Limapuluh Ribu Rupiah.

Umumnya cara yg ditawarkan dlm kasus terbilang excel ini menggunakan kode macro VBA atau menggunakan Addin terbilang excel yg juga sdh kmi bagikan pada halaman lain.

Menggunakan kode VBA atau Addin terbilang rupiah pada excel ternyata memiliki beberapa kekurangan, antara lain:

1. Jika menggunakan addin, kemungkinan fungsi terbilang tidak akan bekerja jika dibuka pada komputer lain.
2. Jika menggunakan kode VBA bagi yg awam akan kesulitan menerapkannya.
3. Jika menggunakan kode VBA maka file tidak bisa disimpan dengan ekstensi .xlsx
4. Dan lain-lain.

Sebenarnya selain menggunakan kode VBA & atau Addin terbilang rupiah excel, kita bisa menggunakan kombinasi beberapa fungsi excel untuk membuat rumus terbilang excel. Tentunya fungsi terbilang ini bisa juga diterapkan pada microsoft excel 2007, 2010, 2013 maupun excel 2016.

Kali ini saya akan berbagi dua macam cara membuat rumus terbilang excel. Yang pertama untuk rumus terbilang rupiah misalnya angka 1.500.000 menjadi Satu Juta Lima Ratus Ribu. Yang kedua rumus terbilang excel untuk merubah angka ke kata misal 89,90 menjadi Delapan Sembilan Koma Sembilan Nol

• Rumus Terbilang Excel Rupiah
• Rumus Terbilang Excel Angka ke Kata

Rumus Terbilang Excel Rupiah

Dalam kasus ini rumus terbilang excel kita gunakan untuk merubah angka menjadi kalimat atau huruf terbilang sprti ejaan bahasa Indonesia pada umumnya. Rumus terbilang manual-nya adalah sbgai brkut:

=IF(A1=0;"nol";IF(A1<0;"minus ";"")& SUBSTITUTE(TRIM(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE( IF(--MID(TEXT(ABS(A1);"000000000000000");1;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");1;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");2;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");3;1)&" trilyun ")& IF(--MID(TEXT(ABS(A1);"000000000000000");4;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");4;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");5;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");6;1)&" milyar ")& IF(--MID(TEXT(ABS(A1);"000000000000000");7;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");7;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");8;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");9;1)&" juta ")& IF(--MID(TEXT(ABS(A1);"000000000000000");10;3)=0;"";IF(--MID(TEXT(ABS(A1);"000000000000000");10;3)=1;"*";MID(TEXT(ABS(A1);"000000000000000");10;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");11;1)&" puluh ")&MID(TEXT(ABS(A1);"000000000000000");12;1)&" ribu ")& IF(--MID(TEXT(ABS(A1);"000000000000000");13;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");13;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");14;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");15;1));1;"satu");2;"dua");3;"tiga");4;"empat");5;"lima");6;"enam");7;"tujuh");8;"delapan");9;"sembilan");"0 ratus";"");"0 puluh";"");"satu puluh 0";"sepuluh");"satu puluh satu";"sebelas");"satu puluh dua";"duabelas");"satu puluh tiga";"tigabelas");"satu puluh empat";"empatbelas");"satu puluh lima";"limabelas");"satu puluh enam";"enambelas");"satu puluh tujuh";"tujuhbelas");"satu puluh delapan";"delapanbelas");"satu puluh sembilan";"sembilanbelas");"satu ratus";"seratus");"*satu ribu";"seribu");0;""));"  ";" "))

Kog rumus excelnya panjang banget? ahahahahahaa... Meskipun panjang kan tinggal copy paste saja.

Pada rumus terbilang diatas referensi sel A1 adalah angka yg akan diubah menjadi teks/huruf terbilang.

Anda bisa juga menambahkan teks rupiah pada akhir rumus di atas, sehingga rumus terbilangnya menjadi:

=RumusTerbilang & " Rupiah"

Gunakan fungsi-fungsi microsoft excel untuk merubah besar kecil huruf semisal fungsi PROPER untuk mengubah kapitalisasi huruf angka terbilang.

=PROPER(RumusTerbilang & " Rupiah")

Untuk menggunakan rumus terbilang excel diatas ada beberapa hal yg perlu diperhatikan.

1. excel hanya menampilkan maksimal 15 digit angka. Jadi jika anda membutuhkan lebih dari 15 digit rumus diatas tidak akan menghasilkan fungsi terbilang sbgaimana mestinya.
2. Rumus terbilang excel diatas tidak bisa menampung angka dibelakang koma, jika anda membutuhkan angka dibelakang koma jangan menggunakan rumus diatas atau pisahkan dulu antara angka depan koma & belakang koma. Untuk kebutuhan ini slahkan baca tutorial tentang pembulatan excel.
3. A1 pada rumus diatas adalah sel dimana angka yg akan kita konversi ke kalimat berada jadi slahkan disesuaikan.
4. Jika regional setting komputer anda masih default english rubah ke bahasa Indonesia atau slahkan ganti Titik koma (;) pada rumus excel diatas menjadi koma (,). Untuk kebutuhan merubah karakter teks secara bersamaan slahkan baca artikel tentang fitur FIND and REPLACE.

Untuk penjelasan masing-masing fungsi yg digunakan slahkan baca artikel-artikel belajar excel sebelumnya: Fungsi SUBTITUTE, Fungsi MID, Fungsi TRIM

Rumus Terbilang Excel Angka ke Kata

Dalam kasus ini fungsi terbilang excel kita gunakan untuk merubah angka ke huruf atau kata sprti merubah angka 87,70 menjadi "Delapan Tujuh Koma Tujuh Nol".

Rumus terbilang excel yg bisa kita gunakan adalah:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(TEXT(A1;"#,00"); 0;"Nol ");1;"Satu ");2;"Dua ");3;"Tiga ");4;"Empat ");5;"Lima ");6;"Enam ");7;"Tujuh ");8;"Delapan ");9;"Sembilan ");",";"Koma ")

Referensi A1 pada rumus terbilang diatas adalah sel yg berisi angka yg akan kita ubah menjadi huruf terbilang. Jadi slahkan sesuaikan dengan kebutuhan.

Jika hanya menghendaki satu angka dibelakang koma maka sesuaikan "#,00" menjadi "#,0" atau yg lainnya sesuai kebutuhan.

Untuk kebutuhan yg lain slahkan berekplorasi dengan trial & error ehehehee... misalnya merubah nol dengan kosong, menggunakan fungsi UPPER, menambah kalimat rupiah & lain sbgainya.

Jika anda kreatif anda juga bisa menggabungkan rumus terbilang excel rupiah & rumus terbilang excel angka ke kata.

Demikian smoga bermanfaat.

Khusus untuk angka 1-100 misal sekedar untuk konversi nilai ujian, sebaiknya tidak menggunakan rumus diatas. Namun gunakan fungsi Vlookup. Tutorialnya bisa anda pelajari pada tautan brkut: Rumus Terbilang Excel Manual Dengan Fungsi Vlookup Excel

Untuk penggunaan lebih simple anda bisa menggunakan addin terbilang yg sdh saya bagikan sebelumnya.

Sumber https://www.kelasexcel.id

Bagikan Artikel ini

Berlangganan update artikel terbaru via email: