Rumus VLookup Dengan 2 Tabel Array Data

Bagaimanakah cara menggunakan fungsi atau rumus VLookup dengan 2 tabel data referensi yg berbeda?

Seperti yg sdh kita pelajari pada pembahasan tentang fungsi Vlookup Excel, bahwa fungsi Vlookup hanya bisa digunakan untuk melakukan pencarian data pada 1 tabel referensi saja.

Jika kita memiliki 2 Tabel data array yg mirip, bagaimana cara agar rumus Vlookup bisa memilih tabel data yg tepat sesuai kriteria yg kita kehendaki?

• Rumus Vlookup Dengan 2 Tabel
• Rumus Vlookup-If
• Rumus Vlookup-Choose

Rumus VLOOKUP Dengan 2 Tabel Data

Misalnya Anda memiliki data dengan 2 tabel sprti di bawah ini. Bagaimanakah rumus VLookup yg digunakan untuk mendapatkan nilai Jumlah sesuai dengan tahun & kwartal yg kita pilih.



Secara umum sintaks fungsi VLookup adalah sbgai brkut:

VLOOKUP(NilaiYangDiCari; TabelReferensi; NomorKolom; [RangeLookup])

Pada kasus Vlookup dengan dua tabel data array sprti diatas argument fungsi VLookup yg perlu kita buat otomatis menyesuaikan dengan kriteria adalah argument TabelReferensi.

Jika menginginkan data tahun 2015 maka Vlookup menggunakan tabel data dengan referensi A2:E6. Se&gkan jika mengharapkan jumlah pada tahun 2016 maka fungsi Vlookup harus menggunakan tabel referensi A9:E13.

Se&gkan untuk argument NilaiYangDiCari sama, yakni data Jumlah pada tahun yg bersangkutan yg bisa didapatkan pada kolom no 5 dari tabel referensi.

Untuk mendapatkan hasil sesuai 2 kriteria diatas maka setidaknya kita bisa menggunakan 2 rumus excel yg berbeda.

Yang pertama dengan menggunakan gabungan fungsi IF dengan fungsi VLookup excel. Dan yg kedua dengan menggunakan gabungan fungsi VLookup & fungsi Choose.

Adapun untuk VLookup pada tabel yg sama dengan multi kriteria bisa anda pelajari pada tautan brkut: Cara LookUp Banyak Kriteria dengan INDEX & MATCH

Rumus Gabungan Fungsi IF & VLOOKUP Excel

Sintaks umum fungsi IF excel adalah sbgai brkut:

IF(TesLogika; [KondisiTerpenuhi]; [KondisiTidakTerpenuhi])

Penjelasan lebih detail tentang fungsi IF excel ini bisa anda baca pada tutorial excel brkut: Cara Menggunakan Fungsi IF Pada Microsoft Excel

Rumus If-Vlookup

Untuk mendapatkan data Jumlah dari sintaks atau cara penulisan diatas maka jika digabungkan dengan fungsi VLookup rumus excelnya akan menjadi:

IF(TesLogika; VLookup_1; VLookup_2)

Dimana VLookup_1 adalah rumus Vlookup untuk tabel pertama & VLookup_2 adalah rumus Vlookup untuk tabel kedua.



Untuk contoh kasus diatas maka rumus excel yg digunakan pada cell B17 adalah sbgai brkut:

=IF(B15=2015;VLOOKUP(B16;A2:E6;5;FALSE);VLOOKUP(B16;A9:E13;5;FALSE))

Dengan rumus diatas jika B15 bernilai angka 2015 maka yg akan dipakai adalah rumus Vlookup_1 yakni:

VLOOKUP(B16;A2:E6;5;FALSE)

Dan sebaliknya jika tidak bernilai 2015 maka fungsi IF akan menghasilkan nilai dari rumus Vlookup brkut:

VLOOKUP(B16;A9:E13;5;FALSE)

Rumus Vlookup-If

Selain memasukkan rumus Vlookup kedlm rumus IF sprti diatas, kasus ini bisa juga diselesaikan dengan memasukkan rumus IF ke dlm rumus Vlookup.

=VLOOKUP(NilaiYangDiCari; IF(TestLogika;TabelReferensi1;TabelReferensi2); NomorKolom; [RangeLookup])

Dari sitaks di atas jika evaluasi logika pada fungsi IF bernilai True maka Vlookup akan menggunakan TabelReferensi1 & sebliknya jika False maka Vlookup akan menggunakan TabelReferensi2.

Untuk contoh sprti sebelumnya rumus gabungan Vlookup-If nya adalah sprti brkut:

=VLOOKUP(B16;IF(B15=2015;A2:E6;A9:E13);5;FALSE)

Pada kasus ini nilai A2:E6 & A9:E13, secara otomatis langsung dikenali sbgai referensi Range oleh fungsi Vlookup. Pada fungsi lain mungkin hal ini tidak terjadi & malah menghasilkan nilai error sehingga anda membutuhkan fungsi INDIRECT untuk membuat referensi dari teks.

Jika menggunakan fungsi Indirect, maka rumus di atas menjadi sprti ini:

=VLOOKUP(B16;IF(B15=2015;INDIRECT("A2:E6");INDIRECT("A9:E13"));5;FALSE)

Rumus Gabungan Fungsi VLOOKUP & CHOOSE Excel

Selain menggunakan rumus excel gabungan sprti diatas kita bisa juga menggunakan fungsi CHOOSE excel untuk memilih tabel data yg digunakan oleh fungsi VLookup.

Sintak fungsi Choose sendiri adalah sbgai brkut:

CHOOSE(IndexNumber; Nilai1; [Nilai2]; ...)

Untuk mempelajari lebih lanjut tentang fungsi Choose ini bisa anda temukan pada tautan brkut: Cara Menggunakan Fungsi Choose pada Micrososft Excel

Jika dimasukkan pada fungsi Vlookup maka rumus excelnya menjadi:

VLOOKUP(NilaiYangDiCari; CHOOSE(IndexNumber; Nilai1; [Nilai2]; ...); NomorKolom; [RangeLookup])

Adapun untuk menentukan index number kita menggunakan fungsi logika IF.



Jika diterapkan pada kasus diatas maka rumus excel yg digunakan pada cell B15 adalah:

=VLOOKUP(B16;CHOOSE(IF(B15=2015;1;2);A2:E6;A9:E13);5;FALSE)

Pada rumus diatas tabel referensi yg digunakan oleh VLookup ditentukan oleh referensi yg dihasilkan oleh fungsi Choose.

Se&gkan fungsi Choose sendiri menggunakan hasil dari fungsi IF untuk menentukan nilai referensi range mana yg akan dihasilkan.

CHOOSE(IF(B15=2015;1;2);A2:E6;A9:E13)

Jika B15 bernilai 2015 maka Choose akan memilih referensi ke-1 yg diberikan yakni range A2:E6, & sebaliknya jika bukan 2015 maka akan memilih referesi ke-2 yaitu range A9:E13.

Nah cukup mudah bukan? Jika anda kreatif, saya kira masih banyak solusi lainnya. Hanya saja 2 rumus exel diatas saya kira sdh cukup untuk saat ini.

Berikut beberapa tutorial excel tentang Rumus VLookup yg bisa anda pelajari:

1. Fungsi Vlookup Excel: Contoh Dan Cara Menggunakannya
2. Rumus Vlookup Sebagian Teks (Vlookup, Left, Mid, Right)
3. Rumus Vlookup Ke Arah Kiri
4. Rumus Vlookup Dengan 2 Kriteria/Kondisi
5. Rumus Vlookup Dengan 2 Tabel Data
6. Rumus Vlookup Dengan Banyak Kriteria
7. Rumus VLookUp Dengan 2 Hasil Pencarian atau Lebih
8. Index-Match:Rumus Alternatif Pengganti VLookup
9. Cara Konversi Rentang Nilai Angka ke Huruf Dengan Vlookup Excel
10. Rumus Terbilang Manual Dengan Fungsi Vlookup Excel

Sekarang cara mana yg anda pilih untuk melakukan VLookup dengan 2 Tabel? Jika punya solusi lain jangan sungkan-sungkan untuk berbagi di kolom komentar.
Sumber https://www.kelasexcel.id

Bagikan Artikel ini

Berlangganan update artikel terbaru via email: