Rumus Menghitung Jumlah Data Unik Dengan Fungsi Countif Excel

Jika memiliki data yg mengandung data yg sama (double/duplikat). Bagaimanakah rumus excel yg digunakan untuk mengetahui jumlah data uniknya? (count unique value excel).

Menghitung jumlah data unik berarti mencacah banyak data, namun jika pada data tersebut memiliki duplikat hanya dihitung satu kali saja.

Data unik ini bisa saja berupa teks maupun angka, juga campuran dari keduanya.

Untuk tutorial cara mendapatkan list data uniknya bisa anda pelajari pada halaman: Rumus Excel Mendapatkan Data Unik Tanpa Kembar.

Salah satu cara untuk menghitung jumlah data unik dari sebuah range data pada excel adalah dengan menggunakan rumus-rumus excel brkut:

• Menghitung Jumlah Data Yang Berbeda/Unik
• Menghitung Jumlah Data Yang Berbeda/Unik Yang Mengandung Sel Kosong
• Menghitung Jumlah Data Yang Berbeda/Unik Mengabaikan Sel Kosong

Rumus Menghitung Jumlah Data Unik/Berbeda Di Excel

Untuk menghitung jumlah data unik bisa menggunakan rumus gabungan fungsi Sum & Countif sprti brkut:

=SUM(1/COUNTIF(RangeData; RangeData))

Akhiri dengan Ctrl + Shift + Enter (Array Formula).



Pada contoh diatas jumlah jenis buah pada range A2:A11 dihitung dengan rumus:

=SUM(1/COUNTIF(A2:A11;A2:A11))

Kemudian tekan Ctrl + Shift + Enter, sehingga rumus excel tersebut akan diapit tanda kurung ({...}) sprti yg terlihat di contoh.

Cara kerja rumus excel diatas adalah sbgai brkut:

1. Fungsi Countif akan menghitung jumlah masing-masing jenis buah pada range data: Mangga = 1, Manggis = 3, Rambutan= 1, Sirsak = 1, Manggis = 3, Jeruk = 1, Apel = 2, Manggis= 3, Nanas = 1, Apel = 2
2. Sehingga menghasilkan angka brkut:
   

   {1;3;1;1;3;1;2;3;1;2}

3. Angka diatas kemudian digunakan untuk membagi angka 1.
   

   1/{1;3;1;1;3;1;2;3;1;2}

4. Setlah mendapatkan angka tersebut kemudian dijumlahkan dengan fungsi SUM
   

   =SUM(1/1;1/3;1/1;1/1;1/3;1/1;1/2;1/3;1/1;1/2)

5. Sehingga menghasilkan jumlah unik jenis buah ada 7.

Penjelasan cara kerja rumus diatas sekaligus sbgai penjelasan untuk rumus-rumus excel brkutnya pada tutorial excel kali ini.

Selain menggunakan rumus array gabungan fungsi SUM & COUNTIF diatas, untuk rumus non Array anda bisa menggunakan gabungan fungsi SUMPRODUCT & COUNTIF brkut:

=SUMPRODUCT(1/COUNTIF(RangeData;RangeData))

Pada contoh diatas rumus excel yg digunakan untuk menghitung jumlah jenis buah adalah:

=SUMPRODUCT(1/COUNTIF(A2:A11;A2:A11))

Cara kerja rumus diatas kurang lebih sama dengan cara kerja rumus sebelumnya.

Penjelasan lebih detail untuk masing-masing fungsi bisa anda baca pada laman brkut: Rumus SUM Excel, Rumus SUMPRODUCT Excel, Rumus COUNTIF Excel.

Jika data yg kita hitung jumlah nilai uniknya mengandung sel kosong (blank cells), ternyata kedua rumus excel diatas tidak bekerja sesuai harapan. Kedua rumus diatas akan menghasilkan pesan error #DIV/0! sprti pada gambar ini.

Penjelasan tentang jenis-jenis error bisa anda baca pada : Mengenal 7 Jenis Pesan Error pada Rumus Excel.

Rumus Menghitung Jumlah Data Unik Yang Mengandung Cell Kosong

Jika pada range data yg kita hitung nilai uniknya terdapat sel kosong (blank cells). Maka solusinya adalah dengan menambahkan (&"") pada kriteria fungsi Countif, sehingga rumus excelnya menjadi:

=SUM(1/COUNTIF(RangeData;RangeData&""))

Akhiri dengan Ctrl + Shift + Enter.

Untuk rumus non Array menjadi:

=SUMPRODUCT(1/COUNTIF(RangeData;RangeData&""))

Dan hasilnya sprti pada gambar brkut:



Jika anda cermati, ternyata dengan menggunakan rumus excel diatas sel yg kosong (Blank Cells) juga ikut terhitung. Data unik pada contoh diatas seharusnya 6 (Mangga, Manggis, Rambutan, Jeruk, Apel, Nanas), namun hasil rumus diatas 7 sebab sel kosong juga ikut terhitung sehingga plus 1 menjadi 7 Jenis.

Untuk menandai sel yg mengandung data ganda maupun sebaliknya menandai data unik bisa anda baca pada halaman: Cara Menemukan Data Ganda (Duplikat) & Data Unik Pada Excel

Jika anda bermaksud mengabaikan sel kosong (Blank Cells), maka gunakan rumus excel brkutnya dibawah ini.

Rumus Menghitung Jumlah Data Berbeda & Mengabaikan Cell Kosong

Rumus excel yg digunakan untuk mengetahui jumlah data unik dengan mengabaikan sel kosong (blank cells) adalah sbgai brkut:

=SUM((RangeData<>"")/COUNTIF(RangeData;RangeData&""))

Akhiri dengan Ctrl + Shift + Enter.

Untuk rumus non array bisa menggunakan gabungan Sumproduct & Countif sprti dibawah ini:

=SUMPRODUCT((RangeData<>"")/COUNTIF(RangeData;RangeData&""))

Contoh penerapannya sprti yg terlihat dlm gambar brkut:



Seperti yg terlihat pada gambar diatas dengan menggunakan rumus array:

=SUM((A2:A11<>"")/COUNTIF(A2:A11;A2:A11&""))

Akhiri dengan Ctrl + Shift + Enter.

atau untuk non Array dengan rumus:

=SUMPRODUCT((A2:A11<>"")/COUNTIF(A2:A11;A2:A11&""))

Kita bisa menghitung jumlah nilai unik dari sebuah range data & mengabaikan sel yg kosong (sel kosong tidak dihitung).

Untuk data yg cukup besar, menghitung jumlah data unik dengan fungsi COUNTIF diatas sebenarnya masih kurang maksimal. Untuk performance yg lebih baik bisa anda pertimbangkan untuk menggunakan fungsi FREQUENCY.

Panduan lebih lanjut tentang penggunaan fungsi FREQUENCY untuk menghitung jumlah data unik ini bisa anda baca pada halaman brkut: Menghitung Jumlah Data Unik Yang Berbeda Dengan Excel

Sumber https://www.kelasexcel.id

Bagikan Artikel ini

Berlangganan update artikel terbaru via email: