Cara Memisahkan Nama Depan, Tengah dan Belakang di Excel

Kali ini kita akan belajar menggunakan rumus excel untuk memisahkan kata/kalimat teks atau lebih tepatnya memisahkan nama depan, tengah & belakang pada sebuah teks nama lengkap di Microsoft Excel.

• Memisahkan Nama Lengkap Dengan Fitur "Text To Columns" Excel
• Mengambil Nama Depan
• Mengambil Nama Belakang
1. Nama Belakang Adalah Kata Setlah Spasi Pertama Dan Kosong Jika Nama Lengkap Hanya Terdiri Dari Satu Kosa Kata
2. Nama Belakang Adalah Kata Setlah Spasi Pertama Dan Jika Nama Lengkap Hanya Terdiri Dari Satu Kosa Kata Maka Nama Belakang Sama Dengan Nama Depan
3. Nama Belakang Hanya Kata Setlah Spasi Terakhir
• Mengambil Nama Tengah

Untuk memisahkan kata yg dipisahkan oleh spasi menjadi beberapa kolom sebenarnya relatif mudah. Excel sdh menyediakan sebuah menu khusus untuk melakukan hal ini, yakni dengan menggukan menu "Text to Columns" yg sdh dijelaskan pada halaman lain.

Fitur "Text to Columns" bisa juga kita manfaatkan untuk memisahkan nama depan, tengah & belakang secara manual. Namun terka&g kita membutuhkan rumus-rumus excel khusus untuk memenuhi kebutuhan pemisahan nama yg tidak bisa kita lakukan dengan fitur "Text to Columns".

Sebelum membahas pemisahan nama dengan rumus excel akan saya bahas sedikit tentang penggunaan fitur "Text to Column" ini, baru setlahnya akan saya bahas tentang cara memisahkan nama depan, tengah & belakang menggunakan rumus-rumus microsoft excel.

*File pelengkap rumus excel tentang memisahkan nama ini bisa anda download pada bagian akhir artikel ini.

A. Memisahkan Nama Dengan Fitur Text To Columns

Ikuti langkah-langkah brkut untuk menggunakan fitur Text to Column untuk memisahkan nama berdasarkan spasi.

1. Tandai atau seleksi nama-nama yg akan dipisah-pisahkan
   
   
   
2. Pilih menu TABData--Text to Columns
   
   
   
3. Pada option box pilih Delimited kemudian klik Next
   
   
   
4. Pada options delimiter pastikan Space tercentang kemudian klik Next
   
   
   
5. Beikutnya muncul option data format untuk masing-masing kolom. Jika perlu tentukan format pada masing-masing kolom. Atau biarkan saja.
6. Klik Finish. Selesai
   
   

Setlah melakukan langkah-langkah diatas, teks sdh terpisah sesuai spasi pada teks sebelumnya.

Hasil pemisahan teks diatas adalah sbgai brkut :



Jika anda mempraktekkanya tentu anda tahu bahwa dengan menggunakan fitur text to columns, teks awal yg dipisah tersebut menjadi berubah, yakni terpisah-pisah menjadi beberapa kolom. Dalam kasus tertentu, tentunya bukan yg sprti ini yg kita harapkan dlm pemisahan nama. Untuk itu simak cara pemishan nama depan, tengah & nama belakang brkutnya.

BACA PELAN-PELAN CARA PEMISAHAN NAMA DENGAN RUMUS EXCEL DIBAWAH INI. JANGAN TERGESA-GESA AGAR TIDAK TERSESAT :)

B. Rumus Mengambil Nama Depan

Biasanya nama depan adalah nama sebelum spasi pertama. Untuk mengambil nama depan maka bisa kita lakukan dengan menggunakan fungsi LEFT dengan menggunakan fungsi FIND untuk mencari posisi spasi (" ") pertama dari kiri. Hasil pencarian posisi ini digunakan untuk mengisi jumlah karakter yg diambil dengan fungsi LEFT.

Rumus Excelnya adalah sbgai brkut:

=LEFT(Nama_Lengkap;FIND(" ";Nama_Lengkap;1)-1)

Selain menggunakan fungsi FIND untuk mencari posisi spasi pertama, anda juga bisa menggunakan fungsi SEARCH. Untuk lebih jelasnya perhatikan contoh gambar brkut:



Kenapa jumlah karakter atau posisi spasi harus minus satu (-1)?

Rumus Excel FIND(" ";Nama_Lengkap;1) digunakan untuk mencari posisi spasi pertama, sehingga jika tidak kita kurangi satu maka nama depan yg dihasilkan akan mengandung spasi yg secara kasat mata tidak terlihat di akhir teks nama depan tersebut.

Cara lain agar spasi di akhir teks nama depan tidak ikut tertulis adalah dengan menggunakan fungsi TRIM, sehingga rumus excelnya menjadi:

=TRIM(LEFT(Nama_Lengkap;FIND(" ";Nama_Lengkap;1)))

Contoh penggunaannya sprti gambar brkut:



Lebih tepat menggunakan FIND atau SEARCH? baca penjelasan kedua fungsi ini pada artikel brkut: "Beda Fungsi FIND & SEARCH".

Loh... kog hasilnya ada yg mengandung pesan error #VALUE ?

Seperti yg terlihat dlm kedua contoh diatas untuk nama yg hanya terdiri dari satu kosa kata atau tidak mengandung spasi hasil pengambilan nama depan adalah sebuah pesan kesalahan/error (#VALUE). Hal ini disebabkan rumus yg kita jalankan tidak dapat menemukan spasi (" ") pada nama lengkap.

Untuk mengatasi ini gunakan fungsi IFERROR. sehingga rumus excelnya akan menjadi:

=IFERROR(LEFT(Nama_Lengkap;FIND(" "; Nama_Lengkap;1)-1); Nama_Lengkap)

atau jika menggunakan fungsi TRIM:

=IFERROR(TRIM(LEFT(Nama_Lengkap;FIND(" "; Nama_Lengkap;1))); Nama_Lengkap)

Setalah menggunakan rumus excel tersebut hasilnya akan sprti gambar di bawah ini:



Sebenarnya masih ada sedikit pertanyaan tentang nama depan ini. Bagaimana jika nama depan mengandung gelar? misal : Dr. Setya Budi Pranomo. Jika menggunakan rumus-rumus excel diatas tentunya hasil nama depan adalah "Dr." padahal yg kita harapkan nama depan adalah "Dr. Setya " atau "Setya" saja.

Untuk kasus nama dengan gelar akan kita bahas lain waktu. Sekarang kita lanjut dulu cara mendapatkan nama belakang.

C. Rumus Mengambil Nama Belakang

Cara mengambil nama tengah ini sedikit rumit jadi harap sabar membaca step by stepnya.

Sebelum menetapkan rumus excel mana yg harus digunakan, kita tentukan dulu kriteria nama belakang itu sprti apa jika nama yg akan kita pisahkan tidak terdiri dua kosa kata.

Maksud saya begini, jika namanya hanya terdiri 1 kata misal "Abdurrahman", maka nama belakangnya kosong atau Abdurrahman (sama dengan nama depannya). Jika namanya terdiri dari 3 kosa kata misal "Bhinneka Tunggal Ika" maka nama belakangnya "Ika" saja atau "Tunggal Ika".

Pilihan diatas tentunya terserah mau anda sprti apa. Biasanya pemisahan nama belakang ini juga dipengaruhi apakah selain memisahkan nama depan & belakang anda juga perlu memisahkan nama tengah atau cukup nama depan & belakang saja.

Jika sdh mengambil keputusan model nama belakang sprti apa yg anda gunakan lanjutkan membaca cara mengambil nama belakang di excel brkut ini.

1. Nama Belakang Adalah Kata setlah Spasi Pertama & Kosong Jika Hanya Terdiri Dari Satu Kosa Kata

Untuk model pertama ini, nama belakang adalah selain nama depan. Jika hanya ada nama depan (nama depan hanya terdiri satu kosa kata) maka nama belakangnya kosong. Rumus excel yg kita gunakan untuk model nama belakang ini adalah:

=IFERROR(RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND(" ";Nama_Lengkap;1));"")

Rumus diatas mengambil karakter Nama_Lengkap dari sebelah kanan. Kebalikan dari cara mengambil nama depan sebelumnya.

RIGHT(Nama_Lengkap; ...;1)

Jumlah karakter yg diambil adalah selisih antara jumlah karakter Nama_Lengkap dengan posisi spasi pertama.

LEN(Nama_Lengkap)-FIND(" ";Nama_Lengkap;1)

Jika tidak ditemukan spasi, maka hasilnya kosong ("")

IFERROR( ... ;"")

Contoh mengambil nama belakang dengan rumus ini adalah :



Selain menggunakan fungsi RIGHT anda juga bisa menggunakan fungsi MID untuk memisahkan nama belakang model ini. Rumusnya adalah:

=MID(Nama_Lengkap;FIND(" ";Nama_Lengkap;1)+1;LEN(Nama_Lengkap)-FIND(" ";Nama_Lengkap;1))

Agar bisa diterapkan juga untuk nama yg hanya terdiri dari satu kosa kata tambahkan IFERROR.

=IFERROR(MID(Nama_Lengkap;FIND(" ";Nama_Lengkap;1)+1;LEN(Nama_Lengkap)-FIND(" ";Nama_Lengkap;1));"")

Contoh memisahkan nama belakang dengan rumus ini sbgai brkut:

2. Nama Belakang Adalah Kata setlah Spasi Pertama & Jika Hanya Terdiri Dari Satu Kosa Kata Maka Nama Belakang Sama dengan Nama Depan

Untuk model kedua, nama belakang adalah selain nama depan. Jika hanya ada nama depan (nama depan hanya terdiri satu kosa kata) maka nama belakangnya sama dengan nama depan. Rumus excel yg kita gunakan untuk model ini mirip dengan model pertama hanya beda di bagian terakhir:

=IFERROR(RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND(" ";Nama_Lengkap;1));Nama_Lengkap)

Contoh penerapannya sbgai brkut:



Bisa menggunakan fungsi MID sprti model pertama rumus excelnya adalah:

=IFERROR(MID(Nama_Lengkap;FIND(" ";Nama_Lengkap;1)+1;LEN(Nama_Lengkap)-FIND(" ";Nama_Lengkap;1));Nama_Lengkap)

Contoh penggunaannya:

Perhatikan hasil untuk nama Abdurrahman untuk membedakan hasil rumus model kedua ini dengan rumus model pertama sebelumnya.

3. Nama Belakang Hanya Kata Setlah Spasi Terakhir

Model ketiga ini biasanya digunakan jika selain nama depan & belakang anda juga perlu memisahkan nama tengah.

Untuk Jenis nama belakang ini, misal nama lengkapnya adalah "Bhinneka Tunggal Ika" maka nama belakangnya adalah "Ika". Rumus Excelnya sbgai brkut:

=RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND("*";SUBSTITUTE(Nama_Lengkap;" ";"*";LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")))))

Agar tidak menghasilkan nilai error #VALUE jika ada nama yg hanya terdiri dari satu kosa kata tambahkan IFERROR sprti model-model sebelumnya, Sehingga rumus excelnya menjadi:

=IFERROR(RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND("*";SUBSTITUTE(Nama_Lengkap;" ";"*";LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")))));"")

Contoh penggunaan rumus ini sbgai brkut:



Untuk nama belakang model ini rumusnya memang sedikit rumit, sebab nama lengkap seseorang saat ini kebanyakan terdiri lebih dari dua suku kata belum lagi kalau ada titlenya berderet-deret.

Cara kerja rumus diatas jika dijabarkan lebih lanjut adalah sbgai brkut:

1. Mengambil beberapa karakter dari kanan:
   

   RIGHT(Nama_Lengkap;Banyak_Karakter)

2. Banyak Karakter pada langkah nomor 1 adalah jumlah karakter Nama_Lengkap dikurangi posisi tanda bintang (*).
3. Untuk mencari banyak karakter Nama_Lengkap adalah dengan menggunakan fungsi LEN
   

   LEN(Nama_Lengkap)

4. Sebelum melakukan pencarian tanda bintang, ganti spasi terakhir Nama_Lengkap dengan tanda bintang (*). Untuk melakukan hal ini kita menggunakan fungsi SUBSTITUTE
   

   SUBSTITUTE(Nama_Lengkap;" ";"*";Posisi_Spasi_Terakhir))

5. Untuk mengetahui posisi spasi terakhir kurangi jumlah karakter Nama_Lengkap dengan Nama_Lengkap tanpa spasi
   

   LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")

6. Langkah 4 & 5 jika digabung menjadi:
   

   SUBSTITUTE(Nama_Lengkap;" ";"*";LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")))

7. 7. Untuk mencari posisi tanda bintang (*)
   

   FIND("*";Rumus_Nomor_6)

Garis besar langkah-langkah diatas adalah ganti spasi terakhir dengan tanda bintang & lakukan pengambilan sejumlah karakter setlah tanda bintang tersebut.

Rumus diatas menghasilkan teks kosong ("") jika nama hanya terdiri dari satu kosa kata saja. Jika anda menghendaki nama belakang sama dengan nama depan untuk Nama_lengkap yg terdiri dari satu kosa kata, ganti bagian terakhir rumus diatas dengan referensi nama_lengkap, sehingga rumus excelnya menjadi:

=IFERROR(RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND("*";SUBSTITUTE(Nama_Lengkap;" ";"*";LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")))));Nama_Lengkap)

Perhatikan nama Abdurrahman pada contoh brkut & bandingkan dengan hasil sebelumnya:



Masih punya masalah dengan nama cara memisahkan nama belakang? sampaikan di kolom komentar. Sekarang kita lanjut dulu tentang cara memisahkan atau mengambil nama tengah.

C. Rumus Mengambil Nama Tengah

Setlah memahami cara memisahkan nama depan & nama belakang dengan rumus-rumus excel diatas brkutnya kita akan belajar tenatng cara memisahkan nama tengah.

Karena nama tengah pastinya ada di bagian tengah sebuah nama, fungsi utama yg kita gunakan adalah fungsi MID. Yakni mengambil beberapa karakter teks dimulai dari posisi spasi pertama sebanyak jumlah antara posisi spasi pertama & jumlah karakter setlah spasi terakhir.

Secara lebih sederhana nama tengah adalah selain nama depan & nama belakang. :D

Rumus Excel yg kita gunakan untuk megambil nama tengah ini adalah:

=MID(B2;FIND(" ";Nama_Lengkap;1)+1;FIND(" ";Nama_Lengkap;1)+LEN(RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND("*";SUBSTITUTE(Nama_Lengkap;" ";"*";LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")))))))

Untuk menghindari error pada nama yg hanya terdiri dari satu kosa kata gunakan IFERROR sprti sebelumnya:

=IFERROR(MID(Nama_Lengkap;FIND(" ";Nama_Lengkap;1)+1;FIND(" ";Nama_Lengkap;1)+LEN(RIGHT(Nama_Lengkap;LEN(Nama_Lengkap)-FIND("*";SUBSTITUTE(Nama_Lengkap;" ";"*";LEN(Nama_Lengkap)-LEN(SUBSTITUTE(Nama_Lengkap;" ";"")))))));"")

Hasilnya akan sprti pada gambar dibawah ini:



Sebagai catatan bahawa rumus pengambilan atau pemisahan nama tengah diatas akan menghasilkan teks kosong ("") untuk nama lengkap yg hasny terdiri dari satu atau dua kosa kata.

Jika anda perhatikan lebih teliti sebenarnya rumus-rumus diatas juga mengikut dankan rumus-rumus untuk pemisahan nama depan & belakang yg sdh kita bahas di bagaian atas.

Itulah salah satu alasan saya kenapa nama tengah ini saya bahas setlah membahas nama depan & nama belakang terlebih dahulu. Sehingga pada prakteknya anda tidak harus menggunakan rumus diatas, namun bisa anda sederhanakan lagi.

Caranya bagaimana? Silahkan uji kreatifitas anda. Sebagai pelengkap silahakan download file latihan dibawah ini:

Dropbox
GDrive

*Jika link mati / tidak dapat diakses slahkan lapor via kontak yg tersedia

FacebookTwitterWhatsapp

LINK DOWNLOAD TERKUNCI.
Silahkan SHARE untuk membuka kunci!

Setlah memahami cara mengambil nama depan, tengah & belakang, cobalah untuk membuat sebuah tabel baru dengan kolom nomor urut, nama lengkap. nama depan, nama tengah & nama belakang.

Kemudian isi kolom nomor urut dengan nomor urut. Kemudian isi baris-baris pada nama lengkap dengan nama-nama terserah anda. Usahakan jumlah kata pada nama lengkap bervariasi & cobalah gunakan rumus-rumus excel diatas untuk memisahkna nama-nama tersebut.

Semoga berhasil. :D
Sumber https://www.kelasexcel.id

Bagikan Artikel ini

Berlangganan update artikel terbaru via email: