Cara Menggunakan Fungsi Logika (AND-OR) Pada Array Formula Excel

Pada saat baru menggunakan array formula atau rumus CSE anda akan sadar bahwa ternyata tidak semua fungsi yg disediakan oleh microsoft excel bisa kita gunakan untuk menyusun sebuah rumus array.

Diantara fungsi excel tersebut adalah fungsi-fungsi logika excel semisal fungsi OR & AND. Padahal fungsi-fungsi ini akan sangat kita butuhkan saat kita perlu untuk menyusun sebuah kriteria atau kondisi tertentu dlm rumus array excel yg akan kita buat.

Sebelum melanjutkan membaca tutorial ini sebaiknya anda sdh membaca dua seri pembahasan array formula excel sebelumnya:

1. Pengenalan Rumus Array Pada Microsoft Excel
2. Menggunakan Konstanta Array Pada Rumus Array Excel

Jika sdh mari kita lanjutkan pembahasan mengenai cara menggunakan operasi logika pada rumus array/CSE excel brkut:

• Cara Menggunakan Logika AND Pada Array Formula
• Cara Menggunakan Logika OR Pada Array Formula

Jangan lupa menggunakan CSE (Ctrl + Shift + Enter) dlm menggunakan rumus-rumus Array dibawah ini.

Fungsi AND Pada Array Formula

Pada rumus biasa, fungsi AND digunakan untuk menghasilkan nilai TRUE jika semua kondisi atau kriteria-kriteria yg di terapkan terpenuhi. Pada array formula anda bisa menggunakan operator perkalian/asterik (*) sprti brkut:

Fungsi AND Biasa :

AND(Logika1; Logika2)

Pada rumus array:

(Logika1) * (Logika2)

Untuk lebih jelasnya perhatikan contoh rumus array brkut:



Pada contoh di atas rumus array yg digunakan untuk mendapatkan jumlah dengan kriteria Nama Toko "Segar" & Barang "Jeruk" adalah:

{=SUM((B2:B11=G2)*(C2:C11=G3)*(D2:D11))}

Rumus ini bermaksud mendapatkan jumlah total barang dengan kriteria toko "Segar" & dengan nama barang "Jeruk".

Bagaimana kalkulasi rumus array di ini?

untuk bagian pertama (B2:B11=G2) sbgai brkut:

{"Manis";"Segar";"Segar";"Manis";"Manis";"Segar";"Manis";"Manis";"Manis";"Segar"}="Segar"

Jika nilai pada sel adalah "Segar" maka akan menghasilkan nilai logika "TRUE" & sebaliknya yg tidak bernilai "Segar" akan menghasilkan nilai Logika "FALSE".

{FALSE;TRUE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE}

Untuk bagian kedua (C2:C11=G3) berlaku hal yg sama. Sel yg bernilai "Jeruk" akan bernilai TRUE & selain yg bernilai "Jeruk" akan FALSE.

Akhirnya akan menghasilkan sebuah array brkut:

{FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE}

Masing-masing nilai logika yg bersesuaian pada kedua array di atas dikalikan yg mana fasle mewakili nili 0 & True mewakili nilai 1.

{FALSE*FALSE;TRUE*FALSE;TRUE*TRUE;FALSE*FALSE;FALSE*FALSE;TRUE*TRUE;FALSE*FALSE;FALSE*FALSE;FALSE*TRUE;TRUE*FALSE}

Kemudian menjadi:

{0*0;1*0;1*1;0*0;0*0;1*1;0*0;0*0;0*1;1*0}

Dan hasilnya adalah sbgai brkut:

{0;0;1;0;0;1;0;0;0;0}

Hasil perkalian antara array pertama & kedua ini kemudian dikalikan dengan bagian ke-3 (D2:D11) yakni nilai yg diambil & akan dijumlahkan

{0;0;1;0;0;1;0;0;0;0}*{10;20;10;30;20;20;10;20;10;30}

{0*10;0*20;1*10;0*30;0*20;1*20;0*10;0*20;0*10;0*30}

Nah hasil dari array di atas kemudian dijumlahkan dengan fungsi SUM

SUM({0;0;10;0;0;20;0;0;0;0})

& ketemu angka 30 sprti terlihat pada contoh gambar di atas.

Kalkulasi di atas kalau dibaca saja memang terkesan rumit, padahal ini masih contoh sederhana saja lho...

Pada AND statement array formula masing-masing kondisi akan dikalikan untuk mendapatkan nilai TRUE(1) jika ada salah satu nilai yg tidak terpenuhi maka akan menghasilkan nilai FALSE(0).

Fungsi OR Pada Array Formula

Berbeda dengan fungsi AND, pada rumus biasa fungsi OR akan menghasilkan nilai TRUE jika salah satu kondisi yg diuji sdh sesuai.

Pada rumus array OR Statement ini bisa anda ganti dengan operator penjumlahan/plus (+) sbgai brkut:

Fungsi OR Biasa :

OR(Logika1; Logika2)

Pada rumus array:

((Logika1) + (Logika2))>0

Pada rumus array ini jika penjumlahan masing-masing logika array nilainya lebih dari 0 berarti ada salah satu atau lebih yg sdh memnuhi kriteria atau kondisi.

Untuk lebih jelasnya perhatikan contoh rumus array brkut:

{=SUM(((C2:C11=G2)+(C2:C11=G3)>0)*(D2:D11))}

Bagaimana kalkulasi rumus di atas?

Perhitungan yg dilakukan rumus array di atas kurang lebih sama dengan sebelumnya, hanya saja jika pada contoh sebelumnya masing-masing array bagian pertama & kedua di kalikan pada rumus ini bagian pertama akan dijumlhkan denan bagian kedua & jiki nilainya lebih dari 0 maka akan menghasilkan nilai logika TRUE (1) yg kemmudian akan idkliakan dengan nilai yg akan diambil.

{FALSE;TRUE;TRUE;FALSE;TRUE;TRUE;FALSE;TRUE;TRUE;FALSE}*{10;20;10;30;20;20;10;20;10;30}

{0;1;1;0;1;1;0;1;1;0}*{10;20;10;30;20;20;10;20;10;30}

{0*10;1*20;1*10;0*30;1*20;1*20;0*10;1*20;1*10;0*30}

Kemudian dijumlahkan dengan fungsi SUM excel:

SUM({0;20;10;0;20;20;0;20;10;0})

& menghasilkan angka 100.

Pada OR statement array formula masing-masing kondisi akan jumlahkan & jika nilainya lebih dari 0 mengindikasikan ada salah satu kondisi yg sdh terpebuhi.

Bagaimana dengan statement fungsi logika yg lain (fungsi NOT, XOR, NAND, dll)? Silahkan dicoba utak atik hehehehehe. Jika memang menemui kendala slahkan sampaikan dikolom komentar yg tlah tersedia.

Seri Pembahasan tentang Array Formula Pada Microsoft Excel:

1. Pengenalan Rumus Array Pada Microsoft Excel
2. Cara Menggunakan Konstanta Array Pada Rumus Array Excel
3. Cara Menggunakan Fungsi Logika (AND-OR) Pada Rumus Array Excel
4. Double Unary Operator (--) Pada Rumus Array Excel

Sumber https://www.kelasexcel.id

Bagikan Artikel ini

Berlangganan update artikel terbaru via email: